Configure help wrong

OSS specific Linux discussion (x86/amd64)

Moderators: cesium, dev, kodachi, hannu

Configure help wrong

Postby EthanG » Thu Aug 18, 2011 5:50 pm

Code: Select all
$ ../oss-v4.2-build2005-src-gpl/configure --enable-libsalsa=YES
../oss-v4.2-build2005-src-gpl/configure: Unrecognized command line option --enable-libsalsa=YES

Permitted command line arguments are:

   --enable-libsalsa=YES|NO     - Enable/Disable libsalsa.


Same error received with lower-case "yes".
EthanG
New Member
 
Posts: 2
Joined: Thu Aug 18, 2011 5:38 pm

Re: Configure help wrong

Postby igorzwx » Thu Aug 18, 2011 6:50 pm

EthanG wrote:
Code: Select all
$ ../oss-v4.2-build2005-src-gpl/configure --enable-libsalsa=YES
../oss-v4.2-build2005-src-gpl/configure: Unrecognized command line option --enable-libsalsa=YES

Permitted command line arguments are:

   --enable-libsalsa=YES|NO     - Enable/Disable libsalsa.


Same error received with lower-case "yes".


That is why, perhaps, it is usually "NO".
Code: Select all
"${srcdir}/${_dir}/configure" --enable-libsalsa=NO --regparm


Code: Select all
# $Id: PKGBUILD 53275 2011-08-02 16:11:02Z bluewind $
# Maintainer: Florian Pritz <bluewind@xinu.at>
# Contributor: Paulo Matias <matiasΘarchlinux-br·org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=oss
pkgver=4.2_2004
pkgrel=2
pkgdesc="Open Sound System UNIX audio architecture"
arch=('i686' 'x86_64')
url="http://developer.opensound.com/"
license=('GPL2')
depends=('gcc' 'make' 'kernel26-headers' 'module-init-tools' 'libtool' 'sed')
makedepends=('pkgconfig' 'gawk' 'gtk2' 'findutils')
optdepends=('gtk2: for graphical mixer (ossxmix)')
conflicts=('oss-linux' 'oss-linux-free' 'oss-testing' 'libflashsupport' 'libflashsupport-pulse' 'libflashsupport-oss')
replaces=('libflashsupport-oss')
install=oss.install
backup=('usr/lib/oss/soundon.user')
source=("http://www.4front-tech.com/developer/sources/stable/gpl/oss-v${pkgver/_*}-build${pkgver/*_}-src-gpl.tar.bz2"
   "rm-init-scripts.patch"
   "rc-script"
   "soundon.patch"
   "remove-hal.patch"
   )
md5sums=('256aba264d523fb8ee444aaacfb8d3da'
         'b9a380a0ac8896390d71ac13676f27e1'
         'cbcbce5c03b127df5eafa8faa091492c'
         '65f07fe241bfbf912f76d8b6d8f276b5'
         'cd7f1dc6166bba8c94d96f3a28e948a5')

build() {
   _dir=oss-v${pkgver/_*}-build${pkgver/*_}-src-gpl
   cd "${srcdir}/${_dir}"

   # Avoid these flags conflicting with OSS build system.
   unset CFLAGS
   unset LDFLAGS
   unset OSFLAGS
   unset LIBRARIES
   export NO_WARNING_CHECKS=yes

   # Compile libflashsupport.so only in packaging time, so we avoid
   # conflicts with other packages and ease package management.
   msg "Building libflashsupport.so."
   cd oss/lib
   gcc -shared -fPIC -O2 -Wall -Werror flashsupport.c -o libflashsupport.so

   msg "Preparing the build environment."
   cd "${srcdir}"

   # Create build directory and configure
   rm -rf build
   mkdir build && cd build
   sed -i.bak -e 's/GRC_MAX_QUALITY=3/GRC_MAX_QUALITY=6/g' ${srcdir}/${_dir}/configure
   "${srcdir}/${_dir}/configure" --enable-libsalsa=NO --regparm

   msg "Building OSS."
   make build

   msg "Patching init scripts."
   cd "${srcdir}/build/prototype"
   rm usr/lib/oss/etc/S89oss
   patch -p0 -i "${srcdir}/rm-init-scripts.patch"
   patch -p0 -i "${srcdir}/soundon.patch"
   # remove hal dependency
   patch -p0 -i "${srcdir}/remove-hal.patch"
   rm -rf usr/lib/oss/scripts/oss_usb-create-devices usr/lib/oss/scripts/90-oss_usb-create-device.fdi
}

package() {
   _dir=oss-v${pkgver/_*}-build${pkgver/*_}-src-gpl
   cd "${srcdir}/${_dir}"

   msg "Copying files."

   # Install libflashsupport.so
   install -dm755 "$pkgdir/usr/lib"
   ln -s oss/lib/libflashsupport.so "$pkgdir/usr/lib/libflashsupport.so"

   cd "${srcdir}/build/prototype"
   cp -a * "${pkgdir}"

   chmod -R a+r "${pkgdir}" # All files can have read permission (FS#13815)
   find "${pkgdir}" -type d -exec chmod a+x '{}' \; # Make namcap happy
   install -Dm755 "${srcdir}/rc-script" "${pkgdir}/etc/rc.d/oss"
}


Do you need "libsalsa"?
igorzwx
Known Member
 
Posts: 1000
Joined: Sun Jun 28, 2009 9:31 pm

Re: Configure help wrong

Postby cesium » Thu Aug 18, 2011 7:31 pm

oops - it's a bug in the script. Well, the default is still 'yes', so if you want to enable libsalsa, just don't give that argument...
cesium
Developer
 
Posts: 902
Joined: Sun Aug 12, 2007 12:51 am

Re: Configure help wrong

Postby EthanG » Fri Aug 19, 2011 9:37 am

cesium wrote:Well, the default is still 'yes', so if you want to enable libsalsa, just don't give that argument...

Good to know. Thanks.
EthanG
New Member
 
Posts: 2
Joined: Thu Aug 18, 2011 5:38 pm


Return to Linux

Who is online

Users browsing this forum: Bing [Bot], Yahoo [Bot] and 1 guest